Работа с двоичными данными (SQL Server + ASP) (45759)

Посмотреть архив целиком

Работа с двоичными данными (SQL Server + ASP)

Христофоров Юрий

В статье будет рассказано как можно работать с двоичными данными в SQL Server с помощью связки ASP + ADO. Поставим перед собой три задачи:

загрузить jpg-файл в столбец типа image таблицы SQL Server

выгрузить этот файл с сохранением на диске

отобразить на web-странице изображение, взятое из базы данных

Для начала создадим базу данных в SQL Server - пусть она будет называться test. Далее необходимо создать таблицу в нашей базе данных - назовем ее blob. Для выполнения указанных действий можно воспользоваться инструментом SQL Server Enterprise Manager.

Ниже на скриншоте показана структура этой таблицы:



blob_id - первичный ключ таблицы (поле типа IDENTITY)

Теперь можно приступать к разработке ASP-скрипта для загрузки тестового файла test.jpg в созданную таблицу.

Начиная с версии ADO 2.5 и выше в ADO появился объект ADODB.Stream. Он отлично подходит для работы с двоичными данными. Его мы и будем использовать.

Файл import.asp

<%@ Language=VBScript %>

<%

option explicit

Response.Buffer = True

Response.Expires = 0

Server.ScriptTimeout = 600

Dim cn, rs, objStream, sSQL

Set cn = Server.CreateObject("ADODB.Connection")

Set rs = Server.CreateObject("ADODB.Recordset")

Set objStream = Server.CreateObject("ADODB.Stream")

cn.Open "Provider=SQLOLEDB.1;Initial Catalog=test;Data Source=localhost;UID=yura;PWD=yura;"

sSQL = "SELECT * FROM blob WHERE blob_id=0"

rs.Open sSQL, cn, 1, 3

rs.AddNew

objStream.Type = 1

objStream.Open

' путь к файлу для загрузки

objStream.LoadFromFile(Server.MapPath("./") & "\test.jpg" )

rs.Fields("name").Value = "Тестовая картинка"

rs.Fields("blob_file").Value = objStream.Read

rs.Update

rs.Close

objStream.Close

cn.Close

Set rs = Nothing

Set objStream = Nothing

Set cn = Nothing

%>

Файл успешно загружен !

Теперь напишем скрипт для экспорта двоичных данных из базы данных в jpg файл.

Файл export.asp

<%@ Language=VBScript %>

<%

option explicit

Response.Buffer = True

Response.Expires = 0

Server.ScriptTimeout = 600

Dim cn, rs, objStream, sSQL

Set cn = Server.CreateObject("ADODB.Connection")

Set rs = Server.CreateObject("ADODB.Recordset")

Set objStream = Server.CreateObject("ADODB.Stream")

cn.Open "Provider=SQLOLEDB.1;Initial Catalog=test;Data Source=localhost;UID=yura;PWD=yura;"

' запрос однозначно получающий запись из таблицы

' в данном случае для примера blob_id = 1

' в Вашем случае это может быть другое число

sSQL = "SELECT * FROM blob WHERE blob_id=1"

rs.Open sSQL, cn, 1, 3

objStream.Type = 1

objStream.Open

objStream.Write rs.Fields("blob_file").Value

' папка, где сохраняется файл, должна иметь NTFS права на чтение/запись для

' интернет-пользователя (обычно IUSR_<имя_компьютера>)

' в данном случае - это текущая папка

objStream.SaveToFile Server.MapPath("./") & "\test_from_db.jpg", 2

rs.Close

objStream.Close

cn.Close

Set rs = Nothing

Set objStream = Nothing

Set cn = Nothing

%>

Файл успешно сохранен из базы данных !

Теперь напишем скрипт для получения изображения из базы данных и непосредственного отображения на web-странице.

Файл img.asp

<%@ Language=VBScript %>

<%

option explicit

Response.Buffer = True

Response.Expires = 0

Server.ScriptTimeout = 600

Response.ContentType = "image/jpeg"

Dim cn, rs, sSQL, binStream

Set cn = Server.CreateObject("ADODB.Connection")

Set rs = Server.CreateObject("ADODB.Recordset")

cn.Open "Provider=SQLOLEDB.1;Initial Catalog=test;Data Source=localhost;UID=yura;PWD=yura;"

' запрос однозначно получающий запись из таблицы

' в данном случае для примера blob_id = 1

' в Вашем случае это может быть другое число

sSQL = "SELECT * FROM blob WHERE blob_id=1"

rs.Open sSQL, cn, 1, 3

binStream = rs.Fields("blob_file").Value

rs.Close

cn.Close

Set rs = Nothing

Set cn = Nothing

Response.BinaryWrite binStream

%>

ASP-скрипт img.asp можно указать в атрибуте src тега img:

Файл img_test.asp

<%@ Language=VBScript %>

Список литературы

Для подготовки данной работы были использованы материалы с сайта http://www.activex.net.ru/



Случайные файлы

Файл
103498.rtf
95237.rtf
124369.rtf
142774.rtf
35290.rtf




Чтобы не видеть здесь видео-рекламу достаточно стать зарегистрированным пользователем.
Чтобы не видеть никакую рекламу на сайте, нужно стать VIP-пользователем.
Это можно сделать совершенно бесплатно. Читайте подробности тут.