Turbo Delphi (ЛР 6 Процедурные типы)

Посмотреть архив целиком

7


ЛР 6. Процедурные типы и модули


ЛР 6. Процедурные типы и модули

Составьте программу, обеспечивающую для функции f(x), выбираемой из заданного набора (см. ниже), вычисление значений аргумента в произвольном диапазоне [a,b], разбиваемом на N подынтервалов, задаваемыми пользователем, и представление в табличном виде:

  1. в произвольных сочетаниях значений самой функции, приближенными значениями её первой f′(x) и второй f″(x) производных и накапливаемых значений интеграла на соответствующих значениях аргумента (пример задания исходных данных и отображения результатов представлен на рис. 1),

  2. приближения корней уравнения f(x)=0 и значений функции в них (см. рис. 2),

  3. приближений экстремумов f(x) и значений функции в них (см. рис. 3).


Рис. 1.


Рис. 2.


Селекторные кнопки с подписями ФУНКЦИИ (RadioButton1), КОРНИ (RadioButton2) и ЭКСТРЕМУМЫ (RadioButton3) в блоке (GroupBox1) с заголовком ВИДЫ РАБОТ представляют альтернативные варианты перечисленных выше работ (см. рис. 1, рис. 2, рис. 3).

Флажки (CheckBox1, CheckBox2, CheckBox3, CheckBox4) в блоке (GroupBox2) с заголовком ТАБЛИЦЫ позволяют выбрать любую комбинацию столбцов таблицы, представляющих вычисленные значения функции (F(X)), интеграла (Интеграл F(X)), производной (F′(X)) и второй производной (F″(X)) функции (на рис. 1 представлен выбор Интеграл F(X), F(X) и F″(X)).


Рис. 3.


Макет формы должен иметь вид рис. 4.

Рис. 4.


Раскрывающийся список (ComboBox1) с поясняющим текстом ВЫБЕРИТЕ ФУНКЦИЮ позволяет выбрать функцию, для которой будут выполняться вычисления, а поля ввода (Edit1, Edit2, Edit3) c поясняющими текстами X0, X1 и N – задать интервал значений аргумента и число его подынтервалов, границы которых будут представлять значения аргумента, используемые в вычислениях.

Программа, помимо основного модуля (unit Form1), должна содержать модуль (unit Funkcii) с объявлениями функций, для которых должны выполняться вычисления, и модуль (unit Raboty), содержащий процедуры, выполняющие эти работы.

Объявления функций, для которых выполняются вычисления, вынесены в отдельный модуль Funkcii, чтобы можно было менять состав этих функций, не редактируя всей программы, или просто заменяя этот модуль другим подобным.

Объявления процедур, выполняющих работы над функциями, вынесены в отдельный модуль, чтобы в случае изменения этих процедур (например, при смене реализуемых ими методов) не затрагивать другие части программы.

МОДУЛЬ Funkcii, содержащий объявления функций, для которых, по выбору пользователя программы, будут выполняться вычисления, должен иметь следующую организацию.

  1. в интерфейсной части обязательно должны быть

    1. объявлены типы

    2. tFuncX=function(x:extended):extended;//тип функций

    3. объявлены переменные

ArrFuncX:array[0..3] of tFuncX;//массив имён объявляемых функций

ArrNameFuncX:array[0..3] of string;//массив текстов, отображаемых для

//выбора функции пользователем

    1. объявлены заголовки функций, доступных в других модулях, к которым будет подключен данный.


    1. подключены модули, необходимые для вычисления значений функций, объявляемых в модуле и доступных в других модулях, к которым будет подключен данный,

  1. в части реализации должны быть

    1. подключены модули, необходимые для вычисления значений функций, объявляемых в модуле и доступных в других модулях, к которым будет подключен данный,

    2. даны описания функций.

  2. в части инициализации следует

    1. заполнить массив ArrFuncX именами функций, объявленных в интерфейсной части,

    2. заполнить массив ArrNameFuncX текстами, соответствующими именам функций в массиве ArrFuncX, отображаемыми для их выбора пользователем.


МОДУЛЬ Raboty, содержит объявления процедур, выполняющих вычисления и сохранение в массиве значений заданной параметром функции, приближенных значений интеграла, первой и второй производных, корней уравнения, экстремумов.

  1. в интерфейсной части должны быть

    1. предложение использования модуля Funkcii

    1. объявление типа

tArrFX=array of extended;//тип массива для хранения результатов вычислений

    1. объявления заголовков процедур, вычисляющих на границах N подынтервалов интервала [a,b]

значений аргумента x и сохраняющие в массиве ArrFX

- значения функции f(x)

procedure FotX(f1:tFuncX;a,b:extended;N:integer;out ArrFX:tArrFX)

- приближенные значения определённого онтеграла, x≤b

procedure Integtal(f1:tFuncX;a,b:extended;N:integer;out ArrFX:tArrFX)

  • приближенные значения первой производной f’(x)

procedure dF_dX(f1:tFuncX;a,b:extended;N:integer;out ArrFX:tArrFX)

  • приближенные значений второй производной f″(x)

procedure d2F_dX2(f1:tFuncX;a,b:extended;N:integer;out ArrFX:tArrFX)

  • приближенные значений корней уравнения f(x) =0

procedure Korni(f1:tFuncX;a,b:extended;N:integer;out ArrFX:tArrFX)

  • приближенные значений экстремумов функции f(x)

procedure Extremumy(f1:tFuncX;a,b:extended;N:integer;out ArrFX:tArrFX)

  1. В части реализации должны быть описания процедур и, при необходимости – предложение использования других модулей, необходимых для их выполнения.

МОДУЛЬ Form1 в разделе реализации должен содержать.

  1. Предложение использования модулей Tablicy и Funkcii.

  2. Объявление глобальной переменной FuncX типа tFuncX, предназначенной для хранения имени функции, выбранной пользователем в раскрывающемся списке (ComboBox).

  3. Подпрограммы

    1. Обработчик создания формы, в котором следует скопировать в раскрывающийся список (компонент ComboBox) строки из массива ArrNameFuncX (см. модуль Funkcii), представляющие выбираемые пользователем функции., а также присвоить переменной FuncX значение ArrFuncX[0], которое будет использоваться по умолчанию в начале работы программы (см. рис 5).

procedure TForm1.FormCreate(Sender: TObject);

var i:integer;

begin

//добавить в раскрывающийся список тексты с именами,

//представляющими функции, используемые в вычислениях,

//из массива ArrNameFunc, заполненного в модуле Funkcii

//в разделе initialization

for i:=0 to high(ArrNameFuncX) do

Form1.ComboBox1.AddItem(ArrNameFuncX[i],Sender);

//выбор функции, соответствующей строке

//с индексом 0 компонента ComboBox1

FuncX:=ArrFuncX[0];

//и вывод соответствующего ему текста

ComboBox1.SelText:=ArrNameFuncX[0];

end;//procedure TForm1.FormCreate(Sender: TObject)

Рис. 5.

    1. Обработчик щелчка на кнопке ВЫХОД с единственным оператором close.

    2. Обработчик щелчков на селекторных кнопках группы ВИД РАБОТЫ (): используя свойство Visible блока ТАБЛИЦЫ () группы флажков, сделать так, чтобы блок становиться невидимым после щелчка на кнопке КОРНИ или ЭКСТРЕМУМЫ, и вновь появляться при щелчке на кнопке ФУНКЦИИ.

    3. Обработчик щелчка на кнопке ВЫПОЛНИТЬ, который должен, в зависимости от сделанных установок в блоках ВИД РАБОТЫ и ТАБЛИЦЫ выполнять следующие работы.

Если выделена селекторная кнопка ФУНКЦИИ, то должна строиться таблица, в первой колонке которой будут выведенны N+1() значений аргумента, а следующие колонки (с накапливаемыми значениями интеграла, значениями функции и её производных) должны быть в таблице только если установлены соответствующие флажки в блоке ФУНКЦИИ (см. рис 1).

Если выделена селекторная кнопка КОРНИ, то должна строиться таблица, в колонках которой будут выведенны значения аргумента на границах подынтервалов, на которых функция имеет разные знаки, и соответствующие им значения функции (см. рис 2).

Если выделена селекторная кнопка ЭКСТРЕМУМЫ, то должна строиться таблица, в колонках которой будут выведенны значения аргумента на несмежных границах двух соседних подынтервалов, внутри которых функция достигает экстремума, и соответствующие им и смежной границе значения функции (см. рис 3).

Обработчик щелчка на кнопке ВЫПОЛНИТЬ представлен на рис. 6. Вызываемая из него процедура myTabFunc (см. Рис. 7) используется для сокращения текста программы, выполняя работы, одинаковые при добавлении в таблицу столбцов со значениями функции, приближенных значений производных и накапливаемых значений интеграла функции.


procedure TForm1.Button1Click(Sender: TObject);

var

ArrFX:tArrFX;

i,N:integer;

a,b,hx:extended;

begin

//Выполнение работ для выбранной функции

//и сделанных установок флагов и радиокнопок

//начало интервалв значений аргумента

a:=StrToFloat(Edit1.Text);

//конец интервалв значений аргумента

b:=StrToFloat(Edit2.Text);

//количество подынтервалов аргумента

N:=StrToInt(Edit3.Text);

hx:=(b-a)/(N);//шаг изменения аргумента

if Form1.RadioGroup1.Buttons[0].Checked then begin

//ФУНКЦИИ

//заголовок над таблицей

Form1.Label4.Caption:='ТАБЛИЦА ФУНКЦИЙ';

//начальная ширина окна для отображения таблицы

Form1.Width:=280;

//сначала в таблице один столбец

Form1.StringGrid1.ColCount:=1;

//заголовок столбца значений аргумента

Form1.StringGrid1.Cells[0,0]:='X';

//начальная ширина окна для отображения таблицы

//из одного столбца для значений аргумента

Form1.StringGrid1.Width:=150;

//в таблице всегда StrToInt(Form1.Edit3.Text)+2 строки

//(причём нулевая - заголовочная)

Form1.StringGrid1.RowCount:=N+2;

//заполнение данными столбца Х

for i:=1 to N+1 do

Form1.StringGrid1.Cells[0,i]:=FloatToStr((i-1)*hx);

if Form1.CheckBox1.Checked then begin

//будет вычислен ИНТЕГРАЛ

Integtal(FuncX,a,b,N,ArrFX);

myTabFunc('Интеграл',ArrFX);

end;

if Form1.CheckBox2.Checked then begin

//будет вычислена выбранная ФУНКЦИЯ

FotX(FuncX,a,b,N,ArrFX);

myTabFunc('F(X)',ArrFX);

end;

if Form1.CheckBox3.Checked then begin

//будет вычислена ПЕРВАЯ ПРОИЗВОДНАЯ

dF_dX(FuncX,a,b,N,ArrFX);

myTabFunc('F''(X)',ArrFX);

end;

if Form1.CheckBox4.Checked then begin

//будет вычислена ВТОРАЯ ПРОИЗВОДНАЯ

d2F_dX2(FuncX,a,b,N,ArrFX);

myTabFunc('F"(X)',ArrFX);

end;

end//ФУНКЦИИ - if Form1.RadioGroup1.Buttons[0].Checked

else if Form1.RadioGroup1.Buttons[1].Checked then begin

//КОРНИ

//будут найдены приближения КОРНЕЙ

Form1.Width:=640;//ширина формы

// заголовок над таблицей

Form1.Label4.Caption

:='ТАБЛИЦА ПРИБЛИЖЕНИЙ КОРНЕЙ';

Form1.StringGrid1.ColCount:=4;//всегда 4 столбца

//вначале только строка заголовков

Form1.StringGrid1.RowCount:=1;

//ширина окна отображения таблицы

Form1.StringGrid1.Width:=510;

//заголовки столбцов

Form1.StringGrid1.Cells[0,0]:='Xпред';

Form1.StringGrid1.Cells[1,0]:='F(Xпред)';

Form1.StringGrid1.Cells[2,0]:='Xслед';

Form1.StringGrid1.Cells[3,0]:='F(Xслед)';

//поиск значений аргумента, предшествующих корням

//уравнения и запись в массив ArrFX

Korni(FuncX,a,b,N,ArrFX);

//задать число строк таблицы

Form1.StringGrid1.RowCount:=length(ArrFX)+1;

//Заполнение столбцов таблицы по данным из массива ArrFX

for i:=0 to high(ArrFX) do begin

//значения аргумента перед корнем

Form1.StringGrid1.Cells[0,i+1]:=FloatToStr(ArrFX[i]);

//значения функции перед корнем

Form1.StringGrid1.Cells[1,i+1]

:=FloatToStr(FuncX(ArrFX[i]));

//значения аргумента за корнем

Form1.StringGrid1.Cells[2,i+1]:=FloatToStr(ArrFX[i]+hx);

//значения функции за корнем

Form1.StringGrid1.Cells[3,i+1]

:=FloatToStr(FuncX(ArrFX[i]+hx));

end;//for i:=0 to high(ArrFX)

end //КОРНИ

else begin //ЭКСТРЕМУМЫ

//будут найдены приближения ЭКСТРЕМУМОВ

Form1.Width:=760;//ширина формы

//заголовок над таблицей

Form1.Label4.Caption

:='ТАБЛИЦА ПРИБЛИЖЕНИЙ ЭКСТРЕМУМОВ';

Form1.StringGrid1.ColCount:=5;//всегда 5 столбцов

//вначале только строка заголовков

Form1.StringGrid1.RowCount:=1;

//ширина окна отображения таблицы

Form1.StringGrid1.Width:=630;

//заголовки столбцов

Form1.StringGrid1.Cells[0,0]:='Xпред';

Form1.StringGrid1.Cells[1,0]:='F(Xпред)';

Form1.StringGrid1.Cells[2,0]:='F(Xэкстр)';

Form1.StringGrid1.Cells[3,0]:='F(Xслед)';

Form1.StringGrid1.Cells[4,0]:='Xслед';

//поиск значений аргумента, предшествующих экстремумам

//функции и запись в массив ArrFX

Extremumy(FuncX,a,b,N,ArrFX);

//задать число строк таблицы

Form1.StringGrid1.RowCount:=length(ArrFX)+1;

//заполнение столбцов таблицы по данным из массива ArrFX

for i:=0 to high(ArrFX) do begin

//значения аргумента перед экстремумом

Form1.StringGrid1.Cells[0,i+1]:=FloatToStr(ArrFX[i]);

//значения функции перед экстремумом

Form1.StringGrid1.Cells[1,i+1]

:=FloatToStr(FuncX(ArrFX[i]));

//значения функции вблизи экстремума

Form1.StringGrid1.Cells[2,i+1]

:=FloatToStr(FuncX(ArrFX[i]+hx));

//значения функции за экстремумом

Form1.StringGrid1.Cells[3,i+1]

:=FloatToStr(FuncX(ArrFX[i]+2*hx));

//значения аргумента за экстремумом

Form1.StringGrid1.Cells[4,i+1]:=FloatToStr(ArrFX[i]+2*hx);

end;//for i:=0 to high(ArrFX)

end;//if _ФУНКЦИИ_else if _КОРНИ_ else _ЭКСТРЕМУМЫ

end;//procedure TForm1.Button1Click(Sender: TObject)

Рис. 6


procedure myTabFunc(const Rabota:string; ArrFX:tArrFX);

var

i:integer;

begin

//увеличить ширину окна, через которое видна таблица

//на 120 пикселей, т.е. на ширину добавляемого столбца

Form1.StringGrid1.Width:=Form1.StringGrid1.Width+120;

//увеличить ширину формы на 120 пикселей, те

//на ширину добавляемого столбца

Form1.Width:=Form1.Width+120;

//увеличить на 1 число столбцов таблицы

StringGrid1.ColCount:=StringGrid1.ColCount+1;

//занести в заголовок последнего столбца название работы

StringGrid1.Cells[StringGrid1.ColCount-1,0]:=Rabota;

//копирование данных из массива ArrFX

//в последний столбец таблицы

for i:=0 to StrToInt(Form1.Edit3.Text) do begin

Form1.StringGrid1.Cells[Form1.StringGrid1.ColCount-1,i+1]

:=FloatToStr(ArrFX[i]);

end;//for i to StrToInt(Form1.Edit3.Text)

end; //procedure myTabFunc(const Rabota:string;ArrFX:tArrFX)

Рис. 7.


    1. Обработчик щелчка на строке раскрывающегося списка, в котором переменной FuncX должно присваиваться имя выбранной пользователем функции. Так как номер строки списка, на котором выполнен щелчок, представлен свойством ItemIndex списка, то к получению желаемого результата приведёт выполнение оператора FuncX:=ArrFuncX[ComboBox1.ItemIndex].

    2. Обработчик двойного щелчка на ячейке первого столбца таблицы со значением аргумента, который должен скопировать значение из указанной ячейки в поле ввода X0 () и из следующей ячейки столбца, если выделена кнопка ФУНКЦИИ, или из ячейки третьего столбца той же стоки, выделена кнопка КОРНИ, или из пятого столбца той же стоки, если выделена кнопка ЭКСТРЕМУМЫ.

  1. Задания для самостоятельного выполнения (см. файл с заданиями к ЛР 6)

    1. Отладить программу для функций, вычисляющих sin(x), tg(x), x+x, x*(x-2), разместив все модули в одной папке. Скопировать все файлы с именем Funkcii в подчинённую папку OldFunkcii и удалить исполняемый файл программы. Убедиться, что программа не выполняется. Командой меню Project\ Remove from Project удалить из проекта модуль . Командой меню Project\ Add to Project добавить в проект модуль из папки, куда он был перемещен. Убедиться, что программа работает.

    2. Создать в подчинённой папке NewFunkcii новый модуль Funkcii с новыми функциями (по своему варианту задания) и заменить им, используя команды меню Project, прежний модуль .